ASP上傳功能的實例分析
本文分享給大家的是關于ASP上傳功能的實例詳解，希望對正在學習ASP的朋友們能夠有幫助。
這個問題已經不是什么新鮮問題了，網上也有大把的教程，但大多數是授人以魚，而不授人以漁，經過辛苦的資料收集，思考，調試，整理，我基本上已經把這個問題從原理上搞清楚了，現在根據我自己的理解，在范例程序的基礎上，加以解釋，希望能對部分網友有所幫助。
請諸位大蝦能對其中的不正或不良這處予以指正。
我想循序漸進，先講一個簡單的，單個圖片文件保存到數據庫。
這個范例共包括三個ＡＳＰ文件和一個數據庫（一個表），全部在同一目錄下。
１、tblImage 表結構（ACCESS 2000）
sn 自動編號 序列號
content-type 文本 圖片類型
image OLE 對象 圖片數據
２、SimpleImageToData.asp：上傳表單及保存圖片到數據庫的代碼部分，主要文件。
<%@ Language=VBScript %>
<% option explicit %>
<%
'從一個完整路徑中析出文件名稱
function getFileNamefromPath(strPath)
getFileNamefromPath = mid(strPath,instrrev(strPath,"\")+1)
end function
'定義數據庫連接字符串
dim cnstr
cnstr = "driver={Microsoft Access Driver (*.mdb)};dbq=" & server.MapPath("./upload.mdb")
%>
<HTML>
<HEAD>
<title>單個圖像保存到數據庫</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
</HEAD>
<body>
<p><a href="SimpleImageToData.asp">上傳圖片</a>
<a href="ShowImageListFromData.asp">顯示圖片</a><hr></p>
<%
if request.ServerVariables("REQUEST_METHOD") = "POST" then
dim sCome, sGo, binData, strData
dim posB, posE, posSB, posSE
dim binCrlf
dim strPath, strFileName, strContentType
binCrlf = chrb(13)&chrb(10) '定義一個單字節的回車換行符
set sCome = server.CreateObject("adodb.stream")
sCome.Type = 1 '指定返回數據類型 adTypeBinary=1,adTypeText=2
sCome.Mode = 3 '指定打開模式 adModeRead=1,adModeWrite=2,adModeReadWrite=3
sCome.Open
sCome.Write request.BinaryRead(request.TotalBytes)
sCome.Position = 0
binData = sCome.Read
'response.BinaryWrite binData '調試用：顯示提交的所有數據
'response.Write "<hr>" '調試用
set sGo = server.CreateObject("adodb.stream")
sGo.Type = 1
sGo.Mode = 3
sGo.Open
posB = 1
posB = instrb(posB,binData,binCrlf)
posE = instrb(posB+1,binData,binCrlf)
'response.Write posB & " | " & posE & "<br>"
sCome.Position = posB+1
sCome.CopyTo sGo,posE-posB-2
sGo.Position = 0
sGo.Type = 2
sGo.Charset = "gb2312"
strData = sGo.ReadText
sGo.Close
'response.Write strData & "<hr>"
posSB = 1
posSB = instr(posSB,strData,"filename=""") + len("filename=""")
posSE = instr(posSB,strData,"""")
if posSE > posSB then
strPath = mid(strData,posSB,posSE-posSB)
'response.Write "本地路徑：" & strPath & "<br>"
'response.Write "文件名：" & getFileNamefromPath(strPath) & "<br>"
posB = posE
posE = instrb(posB+1,binData,binCrlf)
'response.Write posB & " | " & posE & "<br>"
sGo.Type = 1
sGo.Mode = 3
sGo.Open
sCome.Position = posB
sCome.CopyTo sGo,posE-posB-1
sGo.Position = 0
sGo.Type = 2
sGo.Charset = "gb2312"
strData = sGo.ReadText
sGo.Close
strContentType = mid(strData,16) '此處因為固定的，所以省略查找 :-)
'response.Write "圖片類型：" & strContentType & "<hr>"
posB = posE+2
posE = instrb(posB+1,binData,binCrlf)
'response.Write posB & " | " & posE & "<br>"
sGo.Type = 1
sGo.Mode = 3
sGo.Open
sCome.Position = posB+1
sCome.CopyTo sGo,posE-posB-2
sGo.Position = 0
strData = sGo.Read
sGo.Close
'response.Write lenb(strData) & "<br>"
dim cn, rs, sql
set cn = server.CreateObject("adodb.connection")
cn.Open cnstr
set rs = server.CreateObject("adodb.recordset")
sql = "select * from tblImage"
rs.Open sql,cn,1,3
rs.AddNew
rs.Fields("content-type").Value = strContentType
rs.Fields("image").AppendChunk strData
rs.Update
rs.Close
set rs = nothing
cn.Close
set cn = nothing
response.Write "圖片保存成功！" & "<br>"
else
response.Write "沒有上傳圖片！" & "<br>"
end if
set sGo = nothing
sCome.Close
set sCome = nothing
else
%>
<form id="frmUpload" name="frmUpload" action="SimpleImageToData.asp" method="post" target="_self" enctype="multipart/form-data">
<INPUT id="filImage" type="file" name="filImage" size="40">
<BR>
<INPUT id="btnUpload" type="submit" value="Upload" name="btnUpload">
</form>
<%
end if
%>
</body>
</HTML>
